home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Night Owl 9
/
Night Owl CD-ROM (NOPV9) (Night Owl Publisher) (1993).ISO
/
040a
/
qmrwmail.zip
/
RUNWAY.SCR
< prev
Wrap
Text File
|
1993-02-11
|
6KB
|
188 lines
; Credit for this script goes to Phil Gordemer of Compu-Data (609) 232-1245.
; Over the years I have updated portions of it to keep inline with new
; software that has been added to the boards I call. Enjoy! - Ray Novino -
;
; Qmail 4.0 Script for Mail Passing to RunWay BBS (215) 623-6203
; Features of this script:
;
; 1. Will dial phone for a limited of times and giveup.
; 2. Assumes any stop of 5 minutes is a lockup and disconnects
; the phone.
; 3. Confirms messages were actually inserted and resends if needed.
; 4. Creates a capture file of entire session and dialing attempts.
; 5. If carrier is dropped, does NOT attempt to redial so as
; not to get involved in a loop of calling, dropping carrier
; and recalling for hours on end...
; 6. Will delete the .REP file after a successful upload.
; 7. Can handle pre-packed mail from the host
; 8. Resets modem and takes it off hook before returning to DOS to allow
; batch files to continue without callers getting a busy signal.
;
; This script assumes that you have EXTENTED PROMPT turned on in QMAIL
; 4.0 and you do NOT have the logoff before message insertion option on.
; If at anytime carrier is dropped the script will just finish. In
; other scripts, we have had the script redial and try again only to be
; caught in an endless loop of redialing and getting dropped. Since a
; Capture file is created, you can review that and if you see a problem
; can manually dial in.
;
; This script can easily be run from a DOS batch. An example batch file
; might look like this;
;
;@Echo Off
;:Do something here...
;C:
;CD\QMODEM
;Qmodem /S=RunWay.SCR
;:Continue on...
;
; IMPORTANT!!!!!
; Make sure you update the variables in the definitions section below
; which are defined between the lines marked with "########"
; ------------------------------------------------------------------------
; --------------------------- DEFINITIONS -------------------------
TurnOn 8_BIT
TurnOff LINEFEED
TurnOff XON/XOFF
TurnOff NOISE
TurnOff MUSIC
TurnOn SCROLL
TurnOff PRINT
TurnOff ECHO
String QWKFILE REPFILE QWKPATH REPPATH TELNUM LIMIT
String INITIAL DOOR XFER NAME HOSTNAME LANGUAGE
; #####################################################################
Assign HOSTNAME "RunWay BBS" ; name of host system
Assign QWKFILE RUNWAY.QWK ; name of QWK file
Assign REPFILE RUNWAY.REP ; name of REP file
Assign QWKPATH H:\QWKS\ ; DRIVE:\PATH of QWK file
Assign REPPATH H:\REPS\ ; DRIVE:\PATH of REP file
Assign DOOR 2 ; Qmail 4.0 Door #
Assign XFER G ; Transfer Protocol
Assign NAME "First Last PASSWORD" ; My name & password
Assign TELNUM "ATDT 623-4897^M" ; dial string
;Assign TELNUM "ATDT 1 215 623-6103^M" ; dial string
Assign LIMIT 10 ; # of times to dial
Assign INITIAL "AT^M" ; Modem init string
Assign LANGUAGE "2" ; Language to use
SetComm 19200 8 NONE 1 ; Communications Parameters
Capture RUNWAY.CAP ; Name of capture file
; ######################################################################
;---------------------------- Initialize the modem ----------------------
INIT:
Assign 0 $LIMIT
ClrScr
Display "Initializing modem .. "
Delay 1000
Send "$INITIAL"
Waitfor "OK"
;----------------------------- Dial the Board ---------------------------
GETON:
When
When "BUSY" AGAIN
When "NO DIAL TONE" AGAIN
When "NO CARRIER" AGAIN
When "VOICE" GETOUT
Pause 2000
Decr 0
If "$0" < "1" GETOUT
Timeout 45 GETON
clrscr
displayln "Attempting to connect with $HOSTNAME"
displayln "Dial attempts left are $0"
displayln "Dialing String: $TELNUM"
delay 100
Send "$TELNUM"
Waitfor "CONNECT"
goto ONTHESYSTEM
AGAIN:
pause 1000
Send "ATH1^M"
Pause 9000
goto GETON
;-------------------- We have connected to the system ---------------------
ONTHESYSTEM:
When
When "Press (Enter) to continue?" "^M"
When "graphics (Enter)=no?" "N Q^M"
When "(Enter)=yes?" "N^M"
When "What is your first name?" "$NAME^M"
When "messages since" "N^M"
When "Conference members (Enter)=no?" "N^M"
When "More (Y), (N), (NS)" "N^M"
When "Enter Language" "$LANGUAGE^M"
When "(H)elp, More?" "N^M"
When "NO CARRIER" GETOUT
timeout 600 GETOUT
Waitfor "Command?"
Delay 100
Send "QMAIL4 D Y^M"
Delay 100
;------------------------ Call for the download of the packet ----------------
DOWNSECTION:
Send "D^M"
When
When "NO CARRIER" GETOUT
When "<NO TRANSFER>" UPSECTION
When "<OFFLINE>" DOOFFLINE
When "<PRESCAN>" DOOFFLINE
When "these messages (Y/N)?" "Y^M"
Delay 100
DOOFFLINE:
Waitfor "<DOWNLOAD>"
Delay 100
Download $XFER $QWKPATH$QWKFILE
If $SUCCESS UPSECTION
Goto DOWNSECTION
;-------------------------- Lets upload the replies ---------------------
UPSECTION:
Send "^M"
Waitfor "<COMMAND>"
Delay 100
When
When "NO CARRIER" GETOUT
Exist $REPPATH$REPFILE SENDEM
Goto ALLDONE
SENDEM:
Send "U^M"
Delay 100
Waitfor "<UPLOAD>"
Pause 1000
Upload $XFER $REPPATH$REPFILE
If $FAIL UPSECTION
When
When "<MESSAGES NOT INSERTED>" UPSECTION
Dos "Del $REPPATH$REPFILE"
;--------------------------- Lets get out of here ----------------------
ALLDONE:
When
When "<MESSAGES INSERTED>" "^M"
When "Qmail Command?" "G^M"
When "<HANGUP>" GETOUT
Waitfor "<COMMAND>"
Pause 1000
Send "G^M"
Pause 5000
GETOUT:
Hangup
Send "ATZ^M^~^~^~^~^~^~ATH1M0^M"
System Y
Exit